आइंस्टीन की प्रस्तावना समस्या

मैं Habré पर आइंस्टीन के कार्य के सप्ताह को जारी रखना चाहता था। बहुत , बहुत ही गैर-मानक समाधानों के बाद, मैं यह दिखाना चाहूंगा कि तार्किक प्रोग्रामिंग भाषाओं (टॉटोलॉजी के लिए खेद) में तार्किक कार्यों को कैसे हल किया जा सकता है (और होना चाहिए)।
कटौती के तहत, आप देख सकते हैं कि इस कार्य के लिए प्रोलॉग इतनी अच्छी तरह से अनुकूल क्यों है।

कार्य शायद सभी से तंग आ चुका है, इसलिए मैं संक्षिप्त रहूंगा।
कॉमरेड ज़ोनिक्स ने पहले से ही प्रोलॉग की मूल बातें बहुत अच्छी तरह से चित्रित की हैं, इसलिए मेरा काम बहुत सरल है।

हम घर को 5 तत्वों की सूची के रूप में पेश करेंगे, प्रत्येक विशेषता के लिए एक: मालिक की पालतू जानवर, पालतू जानवर, सिगरेट का ब्रांड, पेय और घर का रंग, क्रमशः। कुल 5 घर हैं, इसलिए हम लंबाई 5 की सूचियों (सूचियों) के बीच एक समाधान की तलाश करेंगे।
ऐसा करने के लिए, हमें मानक विधेय की आवश्यकता है:

• सदस्य (एलम, सूची) - यदि एलिम तत्व सूची में है तो सच है
• nth1 (N, List, Elem) - सही है यदि सूची में Elem तत्व N-th पर है (गिनती 1 से शुरू होती है)
• अगली एक्स (एक्स, वाई, लिस्ट) - एक्स में लिस्ट के पहले (बायीं ओर) वाई है तो सही

इसके अलावा, हमें यह कहने में सक्षम होना चाहिए कि 2 घर एक दूसरे के बगल में खड़े हैं। इसे इस सरल विधेय के साथ लागू किया जा सकता है:

neighbors ( X , Y , List ) :- nextto ( X , Y , List ) .
neighbors ( X , Y , List ) :- nextto ( Y , X , List ) .


यही है, या तो वाई के बाईं ओर एक्स, या इसके विपरीत।

और यहाँ, वास्तव में, समाधान है:

einstein :-
/* 0. 5 */
Houses = [ _ , _ , _ , _ , _ ] ,
/* 1. . */
nth1 ( 1 , Houses , [ norwegian , _ , _ , _ , _ ] ) ,
/* 2. . */
member ( [ englishman , _ , _ , _ , red ] , Houses ) ,
/* 3. , . */
nextto ( [ _ , _ , _ , _ , green ] , [ _ , _ , _ , _ , white ] , Houses ) ,
/* 4. . */
member ( [ dane , _ , _ , tea , _ ] , Houses ) ,
/* 5. , Marlboro, , . */
neighbors ( [ _ , _ , marlboro , _ , _ ] , [ _ , cat , _ , _ , _ ] , Houses ) ,
/* 6. , , Dunhill. */
member ( [ _ , _ , dunhill , _ , yellow ] , Houses ) ,
/* 7. Rothmans. */
member ( [ german , _ , rothmans , _ , _ ] , Houses ) ,
/* 8. , , . */
nth1 ( 3 , Houses , [ _ , _ , _ , milk , _ ] ) ,
/* 9. , Marlboro, . */
neighbors ( [ _ , _ , marlboro , _ , _ ] , [ _ , _ , _ , water , _ ] , Houses ) ,
/* 10. , Pall Mall, . */
member ( [ _ , bird , pallmall , _ , _ ] , Houses ) ,
/* 11. . */
member ( [ swede , dog , _ , _ , _ ] , Houses ) ,
/* 12. . */
neighbors ( [ norwegian , _ , _ , _ , _ ] , [ _ , _ , _ , _ , blue ] , Houses ) ,
/* 13. , , . */
member ( [ _ , horse , _ , _ , blue ] , Houses ) ,
/* 14. , Winfield, . */
member ( [ _ , _ , winfield , beer , _ ] , Houses ) ,
/* 15. . */
member ( [ _ , _ , _ , coffee , green ] , Houses ) ,

/* , : ? */
member ( [ Owner , fish , _ , _ , _ ] , Houses ) ,

/* */
print ( 'Owner of the fish: ' ) , print ( Owner ) , nl ,
print ( 'Full Solution: ' ) , print ( Houses ) , nl .



जैसा कि आप देख सकते हैं, कार्यक्रम में लाइनों की कुल संख्या लगभग मूल समस्या की स्थितियों की संख्या के साथ मेल खाती है।
और लाइनें स्वयं मूल स्थितियों की तरह लगभग पढ़ी जाती हैं। प्रस्तावना एक बहुत ही घोषणात्मक भाषा है, हमें केवल यह वर्णन करने की आवश्यकता है कि हम इससे क्या चाहते हैं।
दुभाषिया हमारे लिए सभी गंदे काम करता है, और बहुत जल्दी। मेरी मशीन पर, स्क्रिप्ट 0.08 सेकेंड में चलती है, अगर संकलित किया गया तो यह थोड़ा तेज भी होगा।

प्रोग्राम को शुरू करने के लिए आपको SWI-Prolog स्थापित करने की आवश्यकता है, टेक्स्ट को फ़ाइल में कॉपी करें और ऐसा हैश-बैंग जोड़ें:
# ! / usr / bin / pl - q - t आइंस्टीन - s
(अच्छी तरह से, या यहाँ से कोड ले)

ये कार्य मानक पुस्तकालय में शामिल हैं। पूर्णता के लिए यहां, यह दिखाने के लिए कि "क्लीन" प्रोलॉग पर भी समाधान ज्यादा बड़ा नहीं है।

member ( X , [ X | _]).
member ( X , [_ | Rest ]) :- member ( X , Rest ).

nth1 ( 1 , [ Elem | _], Elem ).
nth1 ( N , [_ | Rest ], Elem ) :- N > 1 , K is N - 1 , nth1 ( K , Rest , Elem ).

nextto ( L , R , [ L , R | _]).
nextto ( L , R , [_ | Rest ]) :- nextto ( L , R , Rest ).


इसके अलावा, स्थिति 0, 1 और 8 को सरल बनाया जा सकता है:

Houses = [[norwegian,_,_,_,_],_,[_,_,_,milk,_],_,_]

तब nth1 विधेय की जरूरत नहीं है, लेकिन मैं मूल के जितना करीब होना चाहता था।