हाल के दिनों में, एडीएसएल से ईथरनेट में संक्रमण के संबंध में, मिकरोटिक से उपकरण का प्रयास करने का एक शानदार अवसर था। इस संबंध में, RB750GL राउटर खरीदा गया था। लोहे का टुकड़ा बाहरी रूप से और कार्यक्षमता और विश्वसनीयता दोनों के मामले में उत्कृष्ट निकला।
नतीजतन, मैंने दोनों चैनलों को छोड़ दिया और स्वचालित स्विचिंग के साथ बैकअप स्थापित करने का निर्णय लिया गया। मानक गेटवे स्विचिंग टूल पूरी तरह से विफलताओं को कवर नहीं करते हैं, इसलिए आपको अपनी स्क्रिप्ट लिखने की आवश्यकता है।

नेटवर्क कॉन्फ़िगरेशन

1. Nhernink Ehernet चैनल राउटर के पहले पोर्ट में प्लग करता है, IP को डीएचसीपी से अधिक प्राप्त करता है, और npt नामक एक pptp कनेक्शन को चुनता है। यह मुख्य कनेक्शन होगा।
2. डोमोलिंक प्रदाता से एडीएसएल चैनल पुल मोड में डीलिंक -2500 से गुजरता है और राउटर के दूसरे पोर्ट में चिपक जाता है, डोमपोलिंक नामक एक पप्पी कनेक्शन ऊपर उठता है। यह एक बैकअप कनेक्शन होगा।
3. राउटर के पोर्ट 3-5 का उपयोग उपकरणों को स्थानीय नेटवर्क से जोड़ने के लिए किया जाता है।

राउटर सेटिंग्स

एक स्थानीय क्षेत्र नेटवर्क पर कंप्यूटरों के लिए कनेक्शन और मस्कारिंग स्थापित करना तुच्छ है और आधिकारिक विकी में विस्तार से वर्णित है।

पीपीपी कनेक्शन को कॉन्फ़िगर करते समय, आपको डिफ़ॉल्ट मार्गों के अतिरिक्त को अक्षम करने की आवश्यकता होती है, और फिर विभिन्न मैट्रिक्स और उपयुक्त टिप्पणियों के साथ स्थैतिक मार्ग बनाते हैं:

/ip route
add comment=MainGW disabled=no distance=1 dst-address=0.0.0.0/0 gateway=nlink scope=30 target-scope=10
add comment=RsrvGW disabled=no distance=2 dst-address=0.0.0.0/0 gateway=domolink scope=30 target-scope=10

अब, चैनल स्विच करने के लिए, बस दूरी पैरामीटर बदलें। इस पैरामीटर के लिए ट्रैफ़िक कम मान वाले चैनल से होकर गुजरेगा।

स्क्रिप्ट

राउटर शुरू करते समय वैश्विक पैरामीटर सेट करना

स्क्रिप्ट को set_global_parameters कहा जाता है

#Main interface name
:global MainIf nlink
#Reserve interface name
:global RsrvIf domolink
#Main interface ip address
:global MainIfAddress ""
#Reserve interface ip address
:global RsrvIfAddress ""

इंटरफेस के आईपी पते का निर्धारण

मुख्य इंटरफ़ेस का आईपी पता निर्धारित करना

स्क्रिप्ट को define_main_if_ip कहा जाता है

:global MainIf
:global MainIfAddress ""
:set MainIfAddress [/ip address get [find interface=$MainIf] address]

यह स्क्रिप्ट इंटरनेट तक पहुंचने के लिए मुख्य इंटरफ़ेस का आईपी पता निर्धारित करती है। यदि यह इंटरफ़ेस अनुपलब्ध है, तो स्क्रिप्ट विफल हो जाएगी, और MainIfAddress चर में एक रिक्त स्ट्रिंग होगी।

बैकअप इंटरफ़ेस का आईपी पता निर्धारित करना

स्क्रिप्ट को define_reserved_if_ip कहा जाता है

:global RsrvIf
:global RsrvIfAddress ""
:set RsrvIfAddress [/ip address get [find interface=$RsrvIf] address]

इन पतों की परिभाषा अलग-अलग लिपियों में बनाई गई है, क्योंकि मैं राउटर पर कई लिपियों में इन मानों का उपयोग करता हूं (उदाहरण के लिए, DynDNS में रिकॉर्ड अपडेट करना), और उपयोगकर्ता फ़ंक्शन यहां नहीं बनाए जा सकते हैं। यह ध्यान दिया जाना चाहिए कि प्रत्यक्ष पता निर्धारण कमांड का उपयोग अन्य लिपियों में नहीं किया जा सकता है, क्योंकि इंटरफ़ेस के साथ समस्याओं के मामले में, वे एक त्रुटि उत्पन्न करते हैं और स्क्रिप्ट को पूरा करने के लिए नेतृत्व करते हैं।

चैनल स्विचिंग

स्क्रिप्ट को कनेक्शन_चेक कहा जाता है

:global MainIf
:global RsrvIf
:global MainIfAddress
:global RsrvIfAddress

:local PingCount 3

#www.ru
:local PingTarget1 194.87.0.50

#ya.ru
:local PingTarget2 87.250.250.203

#google dns
:local PingTarget3 8.8.8.8

#Check main internet connection
:local MainIfInetOk false;

if ($MainIfAddress="") do={delay 5}

if ($MainIfAddress!="") do={
:local PingResult1 [/ping $PingTarget1 count=$PingCount interface=$MainIf]
:local PingResult2 [/ping $PingTarget2 count=$PingCount interface=$MainIf]
:local PingResult3 [/ping $PingTarget3 count=$PingCount interface=$MainIf]

:set MainIfInetOk (($PingResult1 + $PingResult2 + $PingResult3) >= (2 * $PingCount))
}

#Check reserved internet connection
:local RsrvIfInetOk false;

if ($RsrvIfAddress="") do={delay 5}

if ($RsrvIfAddress!="") do={
:local PingResult1 [/ping $PingTarget1 count=$PingCount interface=$RsrvIf]
:local PingResult2 [/ping $PingTarget2 count=$PingCount interface=$RsrvIf]
:local PingResult3 [/ping $PingTarget3 count=$PingCount interface=$RsrvIf]

:set RsrvIfInetOk (($PingResult1 + $PingResult2 + $PingResult3) >= (2 * $PingCount))
}

:put "MainIfInetOk=$MainIfInetOk"
:put "RsrvIfInetOk=$RsrvIfInetOk"

if (!$MainIfInetOk) do={
/log error "Main internet connection error"
}

if (!$RsrvIfInetOk) do={
/log error "Reserve internet connection error"
}

:local MainGWDistance [/ip route get [find comment="MainGW"] distance]
:local RsrvGWDistance [/ip route get [find comment="RsrvGW"] distance]
:put "MainGWDistance=$MainGWDistance"
:put "RsrvGWDistance=$RsrvGWDistance"

#SetUp gateways
if ($MainIfInetOk && ($MainGWDistance >= $RsrvGWDistance)) do={
/ip route set [find comment="MainGW"] distance=1
/ip route set [find comment="RsrvGW"] distance=2
/log info "Switch to main internet connection"
}

if (!$MainIfInetOk && $RsrvIfInetOk && ($MainGWDistance <= $RsrvGWDistance)) do={
/ip route set [find comment="MainGW"] distance=2
/ip route set [find comment="RsrvGW"] distance=1
/log warning "Switch to reserve internet connection"
}

एक विशिष्ट इंटरफ़ेस के माध्यम से पिंग पर ध्यान दें, साथ ही साथ एक चैनल को दोषपूर्ण मानने के लिए मानदंड। मैं तीन अलग-अलग नोड्स को पिंग करता हूं और मानता हूं कि यदि प्रतिक्रियाएं 2/3 से कम आती हैं तो इंटरनेट इस इंटरफेस पर काम नहीं करता है।

योजनाकार

1. राउटर के शुरू होने पर set_global_parameters स्क्रिप्ट एक बार चलाई जाती है।
2. आईपी पते निर्धारित करने के लिए लिपियों को हर 27 सेकंड में चलाया जाता है। यह मान मुख्य स्क्रिप्ट के साथ युगपत प्रारंभ की संख्या को कम करने के लिए चुना गया है।
3. कनेक्शन_ चेक स्क्रिप्ट हर मिनट चलती है।

निष्कर्ष

न्यूनतम लागत पर परिणामी समाधान ने मेरे घरेलू नेटवर्क की विश्वसनीयता में काफी वृद्धि की और स्थानीय प्रदाताओं की सबसे परिष्कृत विफलताओं के साथ सफलतापूर्वक मुकाबला किया, जबकि यह बाहरी नेटवर्क नोड्स की विफलताओं से पर्याप्त रूप से सुरक्षित है।

मिकरोटिक ओएस और बैकअप चैनल पर स्वचालित स्विचिंग